2} Ergänzungen, Hinweise, Korrekturen, Meinungen ~ Schreiben möglich

Hallo onurbi,

versuch doch mal eine externe Suche mit google. Dazu gibst Du in Google beispielsweise folgenden String ein: "nüvi 760" site:http://www.naviboard.de

Der Parameter "site:" schränkt die Suche auf eine ganz bestimmte Website ein, in diesem Fall eben das NaviBoard. Immerhin Zeigt Google mit obigem Suchstring 99 Fundstellen. Die Möglichkeiten der erweiterten Suche bei Google sollten auch funktionieren.

Viel Erfolg!

paul-josef

Zitat von onurbi

Ist dann halt ein Workaround.

Möglicherweise kann man es so nennen. Aber woran bist Du interessiert, an der reinen Lehre, oder an brauchbaren Suchergebnissen?

Nein, im Ernst: Ich kann das höchstens weitergeben, aber selbst nicht beeinflussen.

paul-josef

@ DerMitdemFahrrad,

Betrifft: http://www.naviboard.de/vb/showthread.php?t=18097

Eine sehr schöne und ausführliche Erklärung.
Mich stört allerdings der Satz : "Routen zur Luftlinienplanung hingegen haben keinen Vorteil gegenüber Tracks"
Egal ob man jetzt Routen oder Tracks bevorzugt, ein ganz entscheidender Vorteil von Routen ist das ich sie unterwegs auf dem Gerät erstellen oder/und ändern/erweitern kann. Das geht mit Tracks nicht. Ist ein Track erst einmal auf dem Navi habe ich keine Möglichkeiten mehr ihn zu bearbeiten.
Das bedeutet im Extremfall das wenn ich mir, mit Hilfe von Tracks eine Tour erstellt habe die ich Aufgrund einer Strecken Sperrung nicht gehen/fahren kann, kann ich mit dem Navi nicht mehr all zuviel anfangen, während ich eine Route auch unterwegs noch anpassen kann.

Grüße, Hein

Hallo Hein,

Zitat von Hein-Blöd

Mich stört allerdings der Satz : "Routen zur Luftlinienplanung hingegen haben keinen Vorteil gegenüber Tracks"
Egal ob man jetzt Routen oder Tracks bevorzugt, ein ganz entscheidender Vorteil von Routen ist das ich sie unterwegs auf dem Gerät erstellen oder/und ändern/erweitern kann. Das geht mit Tracks nicht.

Ja, stimmt. Der Admin müsste den Beitrag wieder freischalten, dann kann ich ihn ändern.

Gruß
Andreas

Zitat von DerMitdemFahrrad

Der Admin müsste den Beitrag wieder freischalten

Hallo Andreas,

das können auch die Mods. Beitrag ist freigeschaltet. Sag, wenn Du fertig bist.

@all
Aber bitte nur den Autor hier schreiben lassen, alles andere wird entfernt! Wenn dazu Diskussionsbedarf besteht, bitte neuen Thread eröffnen.

paul-josef

Hallo paul-josef,

Zitat von paul-josef

Beitrag ist freigeschaltet. Sag, wenn Du fertig bist.

Bescheid!

Gruß
Andreas

@ DerMitdemFahrrad

Das ging ja schnell.
So finde ich das jetzt besser .

Danke, Hein

Hallo,

als Neueinsteiger hab ich grad den Teil für das Motorradnavigieren durchgelesen. Dabei ist mir aufgefallen, das (zumindestens bei mir) der Link zu "TTQV-Planungssoftware" nicht funktioniert.

Bye

Hallo Grumbler,

willkommen im Naviboard

Danke für den Hinweis - der Link ist jetzt aktuell.

Grüsse - Anton

Hallo!

Ich hätte hier noch was evtl. FAQ-verdächtiges:

Die Karten von Lambertus (http://garmin.na1400.info/routable.php) haben ja bekanntlich alle dieselbe Family-Id und denselben Family-Name. Das führt dazu, daß für gmapsupp.img (oder entsprechende umbenannte) Dateien auf Systemen, die mehrere Karten unterstützen, jeweils nur _eine_ Karte namens "OSM World routable" angezeigt wird, unter der sich dann die gesamten Dateien vereinen.

So kann man also nur _alle_ derart erzeugten Karten _zusammen_ ein- oder ausschalten. Das kann nervig sein, insbesondere, wenn man Überlappungen (DACHI/Alpenkarte/nur Deutschland) für unterschiedliche Profile/Anwendungszwecke hat. Das Problem wurde auch schon im Thread http://www.naviboard.de/vb/showthread.php?t=38881 angesprochen.

Ich habe mir nun eine Lösung überlegt, die mit den zwei Standardtools (gmt.exe von http://www.anpo.republika.pl/download.html und mkgmap.jar von http://www.mkgmap.org.uk/snapshots) sowie einem einfachen, handgestrickten Batch-Skript auskommt.

Wirft man gmt.exe, mkgmap.jar sowie maprename.bat und die fragliche gmapsupp.img-Datei (die beispielsweise Kacheln von Italien enthält) zusammen in ein Verzeichnis, kann man mit "maprename gmapsupp.img Italien" eine Datei namens "Italien_osm_routable.img" erzeugen, die die gewünschten Informationen enthält und dann im Garmin aus unter dem Namen "Italien" einzeln sicht- sowie an- und abwählbar ist.

Hier die Batchdatei zur freien Verwendung:

<maprename.bat>
@ECHO off

@ECHO maprename batch file version 0.0.1
@ECHO Copyright (C) 2010 Volker Bartheld - http://www.bartheld.net
@ECHO Licensed under GPL v2

REM preliminaries
SETLOCAL ENABLEEXTENSIONS
IF ERRORLEVEL 1 GOTO :NO_EXTENSIONS_ERROR
IF "%1" EQU "" GOTO :USAGE

REM check java VM
java.exe -version > nul
IF ERRORLEVEL 1 GOTO :NO_JAVA_ERROR
@ECHO Java OK...

REM check gmt.exe
gmt.exe -? > nul
IF ERRORLEVEL 2 GOTO :NO_GMT_ERROR
@ECHO gmt OK...

REM check presence of mkgmap.jar
IF NOT EXIST mkgmap.jar GOTO :MKGMAPJAR_ERROR
@ECHO mkgmap.jar OK...

REM if mkgmap.cfg exists, take that one
IF EXIST mkgmap.cfg GOTO :MKGMAPCFG_EXIST

REM generate a mkgmap.cfg template from scratch
@ECHO Creating mkgmap.cfg...

REM add you user-specific settings here!
@ECHO latin1 > mkgmap.cfg
@ECHO route >> mkgmap.cfg
@ECHO net >> mkgmap.cfg
@ECHO remove-short-arcs >> mkgmap.cfg
@ECHO tdbfile >> mkgmap.cfg
@ECHO product-id=1 >> mkgmap.cfg
SET MKGMAP_CREA=1

:MKGMAPCFG_EXIST
REM create temporary directory and copy mkgmap.cfg template there
IF EXIST ~temp RD /s /q ~temp
MD ~temp
COPY /y mkgmap.cfg ~temp\mkgmap.cfg > nul

REM use gmt.exe to split input file
@ECHO Splitting %1...
@ECHO gmt.exe -s %1 -o ~temp
gmt.exe -s "%1" -o "~temp" >> ~temp\gmt.log
IF ERRORLEVEL 2 GOTO :GMT_ERROR

REM family_id is filename of first .img file
FOR /F "usebackq tokens=1 delims=." %%i IN (`dir /b /o:e ~temp\*.img`) DO (
SET FAMILY_ID=%%i
GOTO :ENDLOOP1
)

:ENDLOOP1
SET FAMILY_NAME=%2
IF NOT "%FAMILY_NAME%"=="" GOTO :FAMILY_NAME_SPECIFIED
SET FAMILY_NAME=OSM_%FAMILY_ID%

:FAMILY_NAME_SPECIFIED
SET DESCRIPTION=OSM %FAMILY_NAME% routable
SET COUNTRY_NAME=OSM %FAMILY_NAME%

REM summarize input for mkgmap
@ECHO countryname=%COUNTRY_NAME%
@ECHO description=%DESCRIPTION%
@ECHO family-id=%FAMILY_ID%
@ECHO family-name=%FAMILY_NAME%

REM write renaming configuration to mkgmap.cfg
@ECHO countryname=%COUNTRY_NAME% >> ~temp\mkgmap.cfg
@ECHO description=%DESCRIPTION% >> ~temp\mkgmap.cfg
@ECHO family-id=%FAMILY_ID% >> ~temp\mkgmap.cfg
@ECHO family-name=%FAMILY_NAME% >> ~temp\mkgmap.cfg

REM add input files to mkgmap.cfg
FOR /F "usebackq delims=" %%i IN (`dir /b /o:e ~temp\*.img ~temp\*.typ`) DO (
@ECHO input-file=%%i >> ~temp\mkgmap.cfg
)

REM run mkgmap.jar to combine the map tiles again with new name/id
@ECHO Combining ~temp\gmapsupp.img...
@ECHO java.exe -jar ..\mkgmap.jar --gmapsupp --read-config=mkgmap.cfg
PUSHD ~temp
java.exe -jar ..\mkgmap.jar --gmapsupp --read-config=mkgmap.cfg
POPD
IF ERRORLEVEL 1 GOTO :MKGMAP_ERROR
IF NOT EXIST ~temp\gmapsupp.img GOTO :MKGMAP_ERROR

REM rename gmapsupp.img to something more useful and copy into root directory
REN ~temp\gmapsupp.img %FAMILY_NAME%_osm_routable.img
MOVE ~temp\%FAMILY_NAME%_osm_routable.img .\
@ECHO Created %FAMILY_NAME%_osm_routable.img.

REM remove temporary directory
RD /s /q ~temp

GOTO :CLEANUP

REM ==========================================================================

:USAGE
@ECHO.
@ECHO Usage:
@ECHO maprename [gmapsupp.img] [country]
@ECHO gmapsupp.img: Name of the input file in Garmin gmapsupp-format (mandatory)
@ECHO country: Country name, i. e. "Germany" (optional, family-id will be
@ECHO used as default)
GOTO :CLEANUP

:NO_GMT_ERROR
@ECHO Error: gmt.exe needs to be present.
GOTO :CLEANUP

:GMT_ERROR
@ECHO Error: gmt.exe failed, see ~temp\gmt.log for details.
GOTO :CLEANUP

:NO_JAVA_ERROR
@ECHO Error: Need a java VM environment.
GOTO :CLEANUP

:MKGMAPJAR_ERROR
@ECHO Error: mkgmap.jar not found
GOTO :CLEANUP

:MKGMAP_ERROR
@ECHO mkgmap.jar reported an error, see ~temp\maprename.log for details.
GOTO :CLEANUP

:NO_EXTENSIONS_ERROR
@ECHO Unable to enable command extensions.
@ECHO Either you have a very old command interpreter
@ECHO or you use a too old windows version.
@ECHO Sorry, this won't work on your machine...
GOTO :CLEANUP

REM ==========================================================================

:CLEANUP
REM delete mkgmap.cfg if it has been auto-created
IF "%MKGMAP_CREA%"=="1" DEL /q mkgmap.cfg

REM free environment variables
SET MKGMAP_CREA=
SET COUNTRY_NAME=
SET DESCRIPTION=
SET FAMILY_ID=
SET FAMILY_NAME=

@ECHO.
@ECHO Thank you for using maprename.
</maprename.bat>

Viel Vergnügen!

Volker

Ich habs ausprobiert. Wenn ich einen kompletten ACTIVE LOG speichere gehen keine Daten verloren. Meiner Meinung nach stimmt es schon lange nicht mehr, dass beim Speichern eines Tracks die Uhrzeit und die Höhe aus Speicherplatzgründen nicht mitgespeichert werden. Das Limit mit den 500 Punkten (Garmin 60csx) ist nach wie vor aufrecht. (ein sinnloses Limit, aber...)

LG
Solitair

Interessante Teile des aufgezeichneten ACTIVE LOG lassen sich direkt am GPS-Empfänger isolieren und in einem gesonderten Bereich ablegen. Man spricht dann von einem gespeicherten Track oder vereinfacht von einem Track. Der Bereich für gespeicherte Tracks wird im Gegensatz zum Bereich für das ACTIVE LOG niemals automatisch überschrieben. Aber Vorsicht: Beim Speichern eines Teils des ACTIVE LOG gehen bestimmte Daten der Trackpunkte (Uhrzeit, Höhe) verloren, sodass man gespeicherte Tracks nicht auswerten kann (siehe Abschnitt 3).