Routingfähige OSM Karten, selbergemacht!

Hi,

die Kachelgröße ist so klein gewählt, damit es einfach schneller geht - mich regts grad auf, dass ich keine Karte BaWü+Schweiz hinbekomme...das geht immer wieder schief und es ist nicht erklärbar (für mich!)

Areas ist nicht angepasst, die erstellt der Splitter selbst und da fusche ich auch nicht drin rum.

Update: es liegt daran, dass Osmosis bei den Koordinaten, die er aus der Europakarte rausschneiden soll, keine Fließkommazahlen verarbeiten kann, dann kommt er ausm tritt. wählt man Ganzzahlen tut es. --> unsauber programmiert! es sieht aus, als wäre ein "float2 definiert, sollte aber ein "integer" sein....

vg rene

....nö, daran liegt es auch nicht. Sieht schon wesentlich besser aus, da weniger Leerräume nicht gerendert werden, aber ich bekomme z.B. bei Berlin 3x die A24 angezeigt, 1x scheinbar korrekt mit Kurven und 2x Luftlinie! ...und wenn ich es genau betrachte zieht sich das durch die ganze Box so durch!

Mit welchem Programm kann ich mir die geteilite *.osm und *.img anschaun, um zu prüfen, wo der Fehler entsteht?

Danke
René

hallo koordinatenfreaks

ich muss mich mal einmischen. ich hab ein vista hcx und brauch dafür österreich bayern thüringen sachsen sachsen anhalt. ich hab den ganzen thread gelesen und wollte mal zum einen anführen wie ich vorgegangen bin (bevor ich das hier gelesen habe) und zum anderen eine frage zu den typ files stellen:

wie bin ich vorgegangen:
ein script gebaut (das mein kumpel luke123 bereits hier zum besten gegeben hat), welches jedes bundesland und österreich runterläd von geofabrik. Anschliessend wird jedes gesplittet und danach mit mkgmap alle zu einer gmapsupp.img zusammengeführt (inklusive editing der template.args und areas.list). die karte funktioniert mit routing und lässt sich auf den garmin laden. (habs auch schon mit italien schweiz österreich bayern slovenien thüringen sachsen baden-württemberg sachsen-anhalt hessen probiert (also alle in einer map) - mit erfolg über die grenzen hinweg is es sicher nicht routable wie hier im thread oft angeführt.)
meine anmerkung: ich habs wohl ohne osmosis gemacht, kann sein dass das so nicht richtig ist aber es funzt und es spart platz. wenn ich erst alle ausgepackten osm's fusioniere wäre die osm datei wohl etliche GB gross. ich bau das mit 4GB ram.

Meine grosse Frage:
Ich hab natürlich nur eine sehr hässliche map aufn garmin, hätte gerne eine schöne. ich hab mich jetzt schlau gelesen und rausgefunden:
Die Schönheit meiner Karte hängt mit der TYP-file zusammen.

So. Ich will garnicht erst in Geodäsie promovieren, sondern einfach ganz simpel wissen, wo bekomme ich eine verwendbare (zum Zwecke des Mountainbike-Fahrens) TYP-datei her. Und vielmehr: wie bau ich die in die gmapsupp.img ein.

Was hab ich gelernt:
bei teddy hab ich gelesen ich kann mit mkgmap das typ file einbauen

Zitat

java -jar mkgmap.jar --family-id=42 --gmapsupp *.img teddy.TYP

bzgl. dessen eine Frage:
diese Zeile wende ich auf meine gmapsupp.img an, die ich vorher gebaut habe -> Ergebnis ist, dass die gmapsupp.img so aussieht wie vorher (in Qlandkarte betrachtet) - gehe also davon aus dass das nicht funktioniert hat PS: benutzt wurde die teddy.TYP von seiner Seite.
Weiter hab ich gelesen man sollte die TYP-Datei in denselben Ordner kopieren, in dem auch die gmaspupp.img liegt. Also werden dann beide gelesen? und aus beiden dann die sichtbare Info gebaut?
Daher meine Feststellung:
die TYP-Datei wird nicht in die gmapsupp.img eingebaut? sondern liefert zusätzliche Info?
man könne auch sendmap benutzen? heisst: sendmap schickt beide dateien auf meinen garmin? (und nicht als eine gmapsupp.img)

PS: bin Linuxnutzer aber hätte die Möglichkeit auch xp zu nutzen wenns den unbedingt sein muss.

Wie um Himmels Willen kann ich eine TYP-Datei in meine perfekte gmapsupp.img (die alle meine nötigen Regionen enthält) einbauen.

Vielen Dank an alle!

Gruss,
Pluribootent

*Frage schieb..*
Mit welchem Programm kann ich mir die geteilite *.osm und *.img anschaun, um zu prüfen, wo der Fehler entsteht?

*.osm Texteditor (aber ein gscheiter, und gut Arbeitsspeicher), .img hexeditor oder die bekannten Programme.

kann mir niemand einen tip bzgl. *.typ dateien geben?

Zitat von Pluribootent

kann mir niemand einen tip bzgl. *.typ dateien geben?

Die Teddy.typ kommt nicht in den mkgmap Befehl rein, sondern die Teddy.typ kopiert man ganz zum Schluss dahin, wo auch alle anderen Files sind und bindet das ganze mit mapsettoolkit in mapsource ein:

· Mapsettoolkit starten
· Install Button
· TDB laden (63240000.tdb)
· Overview laden (63240000.img)
· Convert to Families anhaken und eine noch nicht vergebene FID eintragen (z.B.1001)
· Registryname vergeben (z.B. OSM Deutschland)
· Teddy.typ als Typfile wählen
INSTALL Button, fertig (Warnung bzgl. teddy.typ mismatch akzeptieren)

· Das gerade erzeugte Kartenset mit Mapsettoolkit editieren, um z.B. die Draw Priority zu ändern oder den Mapset Namen zu ändern (hier OSM Deutschland)
· Mit TDBChanger04.exe CDMapSet und andere Namen anpassen (das ist der Name, wie er auf dem Garmingerät erscheint, hier OSM Deutschland)

So....werde die Tage mal meine neue HW ausprobieren und schaun, ob sich hinsichtlich der Leistungsfähigkeit die Europa-Karte besser verarbeiten lässt. Habe seit dem Wochenende (zwecks Foto/Videobearbeitung und der Laptop hat das zeitliche gesegnet...) einen Athlon Phenom X4 4x3.0 mit 8GB Ram - das ganze mit einem 64bit system. na schaun wir mal!

gruß
rene

...aktuelle GER-Karte von Geofabrik in 984s gesplittet (nodes=600000), die Europa Karte in 3851s - die geschwindigkeit des rechners ist schon top!!

Hallo,
melde mich nach einer größeren Naviboard-Pause (~ 6 Mon.) mal wieder ...

Da ich krankheitsbedingt nun etwas mehr Zeit habe,
habe ich mir wieder mal MKGMAP & den Splitter vorgenommen.

Die Entwicklung ist ja super !
verwendete Versionen:
Splitter: R97 (Sep.2009)
MKGMAP: R1247 (1.Okt.2009)
(unter WinXP SP3- 4GB 32bit und JAVA 6 U 16)

ENDLICH kann man Große Bundesländer ab Hessen-Größe
( 500 MB OSM-Size) und auch Deutschland (7 GB OSM-Size)
ordlich splitten und dann mit MKGMAP kompilieren!

Grenze ?
Weiss eigentlich jemand, wo die Grenze liegt, wo man splitten muß ?
Die muss ja irgendwo zwischen 400 MB und 500MB liegen.

Splitter - Nodes:
Bei Germany.osm ( 7GB - 4.Okt 2009) musste ich auf 1900000 Nodes ( 26 Teile) runter gehen,
ansonsten funktionieren Nodes 2100000 bis 2450000.

Tile-Size:
Wenn beim splitten (eine der) die entstehenden OSM.GZ-Dateien (Tiles)
größer als rund 40 MB sind, besteht die Gefahr, das die
entstehenden IMGs NICHT funktionieren, da kann man das
Splitten gleich wieder abbrechen und die Nodes verringern.
Als beschleunigend hat sich auch die Splitter-Option --cache=%temp% erwiesen
(=Benutzer-TEMP-Verzeichnis)

Echt G... !

Im Falle von Germany.osm dauert es aber auch,bis man die Karte hat.
- splitten ( 983sec )
- kompilieren knapp 24min
(AMD Athlon-64 X2 4800+ @ 2 x 2,5GHz Brisbane-Core auf
ASUS M2V mit A-DATA PC800-CL4 Extreme, normales BIOS-Timing (not overclocked !))

Erfahrungswerte - Positiv (mit abgeschaltener Garmin-MAP)
Meine selber kompilierte Karte von Sachsen (23.9.09) habe ich
genutzt, um 12 (bereits gespeicherte) POIs beruflich anzufahren.
Das Routing hat auch tadelos geklappt !!

Erfahrungswerte - Negativ (mit abgeschaltener Garmin-MAP):
Eine von Lambertus erstellte Karte hatte ich am 1.9.09
genutzt, um mich von Sachsen nach Müchnen und zurück "leiten" zu lassen.
(Ich kannte die Strecke)
Die hinfahrt hat auch via Regensburg-A93 geklappt.
Für die Rückfahrt wollte mich das Navi partout via Nürnberg-A9 schicken.
Erst als ich auf der A93 verblieb und weiterfuhr,
kam dann irgendwann "No Route" und die Navigation war aus.
Auch mehrfaches neustarten (Zieleingabe) funktionierte NICHT.

Habe dann auf die Garmin-Map zurück geschalten und es funktionierte wieder.
Also 100 % Verlass ist da noch nicht, aber ich bin optimistisch !

Wie sind eure Erfahrungen ?

Hallo Board-Nutzer,
habe mal das kompilieren der Deutschlandkarte auf
verschiedenen Rechnern ausprobiert & gemessen.
Anbei der tabellarische Vergleich:

Gut ist zu sehen, das ein 64bit - Betriebssystem ( x64 OS)
schon einen Vorsprung vor der 32bittigen Version bringt, gerade
bei derart großen Brocken von OSM-Dateien, wo der RAM & Cache eine
immer wichtigere Rolle spielt.

Unter 32bit OS bleiben von physisch 8 GB RAM rund 3-3,5 GB übrig,
davon sind für JAVA um die 1,4 GB zugewiesen ( -Xmx1400m ).

Europa-MAP auf x64-OS-PC:
Die Europamap vom 7.10.2009 ( entpackt 31.785.260 kB ) also rund 32 GB groß
dauert auf dem gleichen PC 1 mit 8GB RAM (die auch unter x64 voll nutzbar sind!) knapp über 2:03 h

der JAVA-Cache wurde auf -Xmx7400m festgelegt (also 7,4 GB von 8GB RAM)
und die Nodes auf 1.200.000 festgelegt (= 173 Tiles)
Die GMAPSUPP ist dann knapp 1,47 GB groß.

Auf einen 32bit-OS dürfte es wohl mindestens 5h dauern ?!

Hallo,
die Detailtabelle -siehe PDF-Datei oben -

Hallo!

Bin in den Thread quereingestiegen und möchte nur kurz meine Erfahrungen kundtun:

Die Karten von Lambertus (http://garmin.na1400.info/routable.php) haben ja bekanntlich alle dieselbe Family-Id und denselben Family-Name. Das führt dazu, daß gmapsupp.img (oder entsprechende umbenannte) Dateien auf Systemen, die mehrere Karten unterstützen, jeweils nur _eine_ Karte als "OSM World routable" angezeigt wird, unter der sich dann die gesamten Dateien tummeln.

So kann man also nur _alle_ derart erzeugten Karten _zusammen_ ein- oder ausschalten. Das kann nervig sein, insbesondere, wenn man Überlappungen (DACHI/Alpenkarte/nur Deutschland) hat. Das Problem wurde auch schon im Thread http://www.naviboard.de/vb/showthread.php?t=38881 angesprochen.

Ich habe mir nun eine Lösung überlegt, die mit den zwei Standardtools (gmt.exe von http://www.anpo.republika.pl/download.html und mkgmap.jar von http://www.mkgmap.org.uk/snapshots) sowie einem einfachen, handgestrickten Batch-Skript auskommt.

Wirft man gmt.exe, mkgmap.jar sowie maprename.bat und die fragliche gmapsupp.img-Datei in ein Verzeichnis, kann man mit "maprename gmapsupp.img Italien" eine Datei namens "Italien_osm_routable.img" erzeugen, die die gewünschten Informationen enthält und dann im Garmin aus unter dem Namen "Italien" einzeln sicht- sowie an- und abwählbar ist.

Hier die Batchdatei zur freien Verwendung:

<maprename.bat>
@ECHO off

@ECHO maprename batch file version 0.0.1
@ECHO Copyright (C) 2010 Volker Bartheld - http://www.bartheld.net
@ECHO Licensed under GPL v2

REM preliminaries
SETLOCAL ENABLEEXTENSIONS
IF ERRORLEVEL 1 GOTO :NO_EXTENSIONS_ERROR
IF "%1" EQU "" GOTO :USAGE

REM check java VM
java.exe -version > nul
IF ERRORLEVEL 1 GOTO :NO_JAVA_ERROR
@ECHO Java OK...

REM check gmt.exe
gmt.exe -? > nul
IF ERRORLEVEL 2 GOTO :NO_GMT_ERROR
@ECHO gmt OK...

REM check presence of mkgmap.jar
IF NOT EXIST mkgmap.jar GOTO :MKGMAPJAR_ERROR
@ECHO mkgmap.jar OK...

REM if mkgmap.cfg exists, take that one
IF EXIST mkgmap.cfg GOTO :MKGMAPCFG_EXIST

REM generate a mkgmap.cfg template from scratch
@ECHO Creating mkgmap.cfg...

REM add you user-specific settings here!
@ECHO latin1 > mkgmap.cfg
@ECHO route >> mkgmap.cfg
@ECHO net >> mkgmap.cfg
@ECHO remove-short-arcs >> mkgmap.cfg
@ECHO tdbfile >> mkgmap.cfg
@ECHO product-id=1 >> mkgmap.cfg
SET MKGMAP_CREA=1

:MKGMAPCFG_EXIST
REM create temporary directory and copy mkgmap.cfg template there
IF EXIST ~temp RD /s /q ~temp
MD ~temp
COPY /y mkgmap.cfg ~temp\mkgmap.cfg > nul

REM use gmt.exe to split input file
@ECHO Splitting %1...
@ECHO gmt.exe -s %1 -o ~temp
gmt.exe -s "%1" -o "~temp" >> ~temp\gmt.log
IF ERRORLEVEL 2 GOTO :GMT_ERROR

REM family_id is filename of first .img file
FOR /F "usebackq tokens=1 delims=." %%i IN (`dir /b /o:e ~temp\*.img`) DO (
SET FAMILY_ID=%%i
GOTO :ENDLOOP1
)

:ENDLOOP1
SET FAMILY_NAME=%2
IF NOT "%FAMILY_NAME%"=="" GOTO :FAMILY_NAME_SPECIFIED
SET FAMILY_NAME=OSM_%FAMILY_ID%

:FAMILY_NAME_SPECIFIED
SET DESCRIPTION=OSM %FAMILY_NAME% routable
SET COUNTRY_NAME=OSM %FAMILY_NAME%

REM summarize input for mkgmap
@ECHO countryname=%COUNTRY_NAME%
@ECHO description=%DESCRIPTION%
@ECHO family-id=%FAMILY_ID%
@ECHO family-name=%FAMILY_NAME%

REM write renaming configuration to mkgmap.cfg
@ECHO countryname=%COUNTRY_NAME% >> ~temp\mkgmap.cfg
@ECHO description=%DESCRIPTION% >> ~temp\mkgmap.cfg
@ECHO family-id=%FAMILY_ID% >> ~temp\mkgmap.cfg
@ECHO family-name=%FAMILY_NAME% >> ~temp\mkgmap.cfg

REM add input files to mkgmap.cfg
FOR /F "usebackq delims=" %%i IN (`dir /b /o:e ~temp\*.img ~temp\*.typ`) DO (
@ECHO input-file=%%i >> ~temp\mkgmap.cfg
)

REM run mkgmap.jar to combine the map tiles again with new name/id
@ECHO Combining ~temp\gmapsupp.img...
@ECHO java.exe -jar ..\mkgmap.jar --gmapsupp --read-config=mkgmap.cfg
PUSHD ~temp
java.exe -jar ..\mkgmap.jar --gmapsupp --read-config=mkgmap.cfg
POPD
IF ERRORLEVEL 1 GOTO :MKGMAP_ERROR
IF NOT EXIST ~temp\gmapsupp.img GOTO :MKGMAP_ERROR

REM rename gmapsupp.img to something more useful and copy into root directory
REN ~temp\gmapsupp.img %FAMILY_NAME%_osm_routable.img
MOVE ~temp\%FAMILY_NAME%_osm_routable.img .\
@ECHO Created %FAMILY_NAME%_osm_routable.img.

REM remove temporary directory
RD /s /q ~temp

GOTO :CLEANUP

REM ==========================================================================

:USAGE
@ECHO.
@ECHO Usage:
@ECHO maprename [gmapsupp.img] [country]
@ECHO gmapsupp.img: Name of the input file in Garmin gmapsupp-format (mandatory)
@ECHO country: Country name, i. e. "Germany" (optional, family-id will be
@ECHO used as default)
GOTO :CLEANUP

:NO_GMT_ERROR
@ECHO Error: gmt.exe needs to be present.
GOTO :CLEANUP

:GMT_ERROR
@ECHO Error: gmt.exe failed, see ~temp\gmt.log for details.
GOTO :CLEANUP

:NO_JAVA_ERROR
@ECHO Error: Need a java VM environment.
GOTO :CLEANUP

:MKGMAPJAR_ERROR
@ECHO Error: mkgmap.jar not found
GOTO :CLEANUP

:MKGMAP_ERROR
@ECHO mkgmap.jar reported an error, see ~temp\maprename.log for details.
GOTO :CLEANUP

:NO_EXTENSIONS_ERROR
@ECHO Unable to enable command extensions.
@ECHO Either you have a very old command interpreter
@ECHO or you use a too old windows version.
@ECHO Sorry, this won't work on your machine...
GOTO :CLEANUP

REM ==========================================================================

:CLEANUP
REM delete mkgmap.cfg if it has been auto-created
IF "%MKGMAP_CREA%"=="1" DEL /q mkgmap.cfg

REM free environment variables
SET MKGMAP_CREA=
SET COUNTRY_NAME=
SET DESCRIPTION=
SET FAMILY_ID=
SET FAMILY_NAME=

@ECHO.
@ECHO Thank you for using maprename.
</maprename.bat>

Viel Vergnügen!

Volker